preinhtml.m4

m4_changequote(<<,>>)m4_dnl
m4_changecom()m4_dnl
m4_divert(-1)m4_dnl

Copyright: 2025 Marco de Beurs
Copyright: 2022, 2023 Octrooicentrum Nederland

Licensed under the EUPL-1.2 or later.
You may obtain a copy of the licence at https://joinup.ec.europa.eu/collection/eupl/eupl-text-eupl-12.

Author: Marco de Beurs


m4_include(translations.m4)

m4_define(<<TitleAuthorDate>>, <<<<TitleAuthorDate($@)>>>>)m4_dnl just a copy
m4_define(<<TitleSubtitleAuthorDate>>, <<<<TitleSubtitleAuthorDate($@)>>>>)m4_dnl just a copy
m4_define(<<QACounter>>, 0)m4_dnl
m4_define(<<IncrQACounter>>, <<
m4_define(<<QACounter>>, m4_incr(QACounter))m4_dnl>>)m4_dnl
m4_define(<<IdQA>>, <<<<QAId_>>QACounter()>>)m4_dnl
m4_define(<<QuestionAnswerHeader>>, <<

| $1 | $2 |
MakeTableQA |>>)m4_dnl
m4_define(<<QuestionAnswerTab>>, <<| $1  | `<button id="IdQA()" onclick="swap_text('IdQA()','$2','$3')">$3</button>`{=html} | IncrQACounter>>)m4_dnl
m4_define(<<ClickToSee>>, <<`<button id="IdQA()" onclick="swap_text('IdQA()','$1','$2')">$2</button>`{=html} IncrQACounter>>)m4_dnl
m4_define(<<PdfFile>>, <<m4_define(PdfFile_$1, $2)m4_dnl>>)m4_dnl
m4_define(<<IncludePDF>>, << <a href=">>PdfFile_$3<<">$2</a>>>)m4_dnl
m4_define(<<PDFRef>>, << <a href=">>PdfFile_$2<<">$1</a>>>)m4_dnl
m4_define(<<SetQuestionTabWidth>>, <<
m4_define(<<QuestionTabWidth>>, >>$1<<)m4_dnl>>)m4_dnl
m4_define(<<SetAnswerTabWidth>>, <<
m4_define(<<AnswerTabWidth>>, >>$1<<)m4_dnl>>)m4_dnl
m4_define(<<CountPrint>>,<<m4_ifelse($1, 0, <<>>, $2<<CountPrint>>(m4_decr($1), $2))>>)m4_dnl
m4_define(<<MakeTableQA>>,<<|:CountPrint(QuestionTabWidth,-)|:CountPrint(AnswerTabWidth,-)>>)m4_dnl
m4_define(<<PrintBibliography>>, <<

m4_include(NoCitesFile)

CountChapter()

# $1 #

::: {#refs}
:::

>>)m4_dnl
m4_define(<<AltText>>, << "$@">>)m4_dnl
m4_define(<<ChapterNumber>>,<<1>>)m4_dnl
m4_define(<<CountChapter>>, <<
:::::: {<<#indexlink>>ChapterNumber}

::::::

m4_define(<<ChapterNumber>>,m4_incr(ChapterNumber))>>)m4_dnl
m4_include(gloshtml.m4)m4_dnl
m4_include(vid.m4)m4_dnl
m4_include(linkshtml.m4)m4_dnl
m4_include(figurehtml.m4)m4_dnl
m4_include(preincommon.m4)m4_dnl
m4_include(GlossaryIncl)
m4_define(<<ToDo>>,<<**$@**>>)m4_dnl
m4_divert(0)m4_dnl