tev/flake.nix at master · Tom94/tev · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
{
  description = "tev — The EDR Viewer";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        package = pkgs.callPackage ./package.nix { };

        ldLibraryPath = pkgs.lib.makeLibraryPath (
          with pkgs;
          [
            wayland
            libxkbcommon
          ]
        );

        commonBuildInputs =
          with pkgs;
          if stdenv.isDarwin then
            [ ]
          else
            [
              binutils
              mesa-demos # for glxinfo, eglinfo
            ];
      in
      {
        packages = {
          default = package;
          tev = package;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = [ package ];
          buildInputs =
            commonBuildInputs
            ++ (
              with pkgs;
              if stdenv.isDarwin then
                [ ]
              else
                [
                  gcc
                  gdb
                ]
            );
          LD_LIBRARY_PATH = ldLibraryPath;
        };

        devShells.clang =
          pkgs.mkShell.override
            {
              stdenv = pkgs.llvmPackages_22.libcxxStdenv;
            }
            {
              inputsFrom = [ package ];
              buildInputs =
                commonBuildInputs ++ (with pkgs; if stdenv.isDarwin then [ ] else [ llvmPackages_22.lldb ]);
              LD_LIBRARY_PATH = ldLibraryPath;
            };

        apps.default = flake-utils.lib.mkApp {
          drv = package;
        };
      }
    );
}