build.gradle

plugins {
  id 'com.github.ben-manes.versions' version '0.47.0'
  id 'org.sonarqube' version '7.3.0.8198'
}

task archiveDeployment(type: Tar) {
  destinationDirectory = file('.')
  archiveFileName = 'deployment.tar'
  into 'deployment'
  from 'deployment'
}

// Set publishing version property globally for this project
configure(subprojects) {
    setProperty('publishing.version', {
      if (findProperty("version.isRelease").toBoolean()) {
        return "${findProperty("version.number")}"
      } else {
        def hash = 'git rev-parse --short HEAD'.execute().text.trim()
        return "${findProperty("version.number")}-SNAPSHOT-$hash"
      }
    }())
}

subprojects {
  apply plugin: 'com.github.ben-manes.versions'

  repositories {
    // Search the local filesystem before attempting remote repositories
    flatDir { dirs "$rootDir/third-party" }
    mavenCentral()
  }

  group = 'gov.nasa.ammos.plandev'

  tasks.withType(JavaCompile) {
    options.compilerArgs << '-Xlint:deprecation' << '-Xlint:unchecked'
    options.encoding = 'UTF-8'
  }

  tasks.withType(Javadoc) {
    options.encoding = 'UTF-8'
    options.addStringOption('Xdoclint:none', '-quiet')
  }
}

// SonarCloud scans run through the Gradle Sonar scanner in .github/workflows/security-scan.yml.
// When using Gradle Sonar plugin, this block replaces the `sonar-project.properties` file which is normally used
sonar {
  properties {
    property "sonar.projectKey", "NASA-AMMOS_aerie"
    property "sonar.organization", "nasa-ammos"
    property "sonar.projectName", "plandev"
    property "sonar.projectVersion", findProperty("version.number")
    property "sonar.python.version", "3.7, 3.8, 3.9, 3.10, 3.11, 3.12"
  }
}